Dall'archivio script > Classic ASP

Evidenziare una parola all'interno di un testo

di Massimo CappellessoMassimo Cappellesso, in Classic ASP, UserScript, Tips,

Con questo script cercheremo ed evidenzieremo una stringa all'interno di un testo.
Per fare questo utilizzeremo la funzione Replace combinata con un ciclo, in quanto la sola funzione non ci permette di mantenere le maiuscole/minuscole della stringa.
Per evidenziare la stringa faremo uso del tag Span e dei CSS.

<%
' Parametri:
' strTesto  stringa in cui cercare
' strParola  stringa da cercare
' strPre  stringa da inserire prima di strParola
' strPost   stringa da inserire dopo strParola
'

Function EvidenziaParola(strTesto, strParola, strPre, strPost)
  Dim intPos, intLen, intLenAll
  Dim strTemp
  
  intLen = Len(strParola)
  intLenAll = intLen + Len(strPre) + Len(strPost) + 1

  strTemp = strTesto

  If intLen > 0 And Len(strTemp) > 0 Then
    intPos = InStr(1, strTemp, strParola, 1)
    Do While intPos > 0
      strTemp = Left(strTemp, intPos - 1) & strPre & Mid(strTemp, intPos, intLen) & strPost & Mid(strTemp, intPos + intLen)
      intPos = InStr(intPos + intLenAll, strTemp, strParola, 1)
    Loop
  End If
  
  EvidenziaParola = strTemp
End Function


Testo = "Tutto quello che con Classic ASP è stato difficile da implementare, con ASP.NET diventa banale, anche se con le Classic ASP ancora ci arrangiamo ;)"
Parola = "asp"

%>
<html>
<head>
<style> span {background-color: #B0C4DE;} </style>
</head>
<body>
<%
Response.write (EvidenziaParola(Testo, Parola, "<span>", "</span>"))
%>
</body>
</html>

Commenti

Visualizza/aggiungi commenti

| Condividi su: Twitter, Facebook, LinkedIn
Aggiorna

Per inserire un commento, devi avere un account.

Fai il login e torna a questa pagina, oppure registrati alla nostra community.

Approfondimenti

Nessuna risorsa collegata

I più letti di oggi