Un mini sistema di commenti con ASP
Lo script di oggi permette di aggiungere a qualsiasi pagina un semplice sistema di commenti.
Tutto quello che dovete fare è creare una pagina che includa il codice sotto riportato.
Verrà creato l'elenco dei commenti, con una form per aggiungerne di nuovi:
<%
Sub Commenti(Pagina)
strConn = "Provider=Microsoft.Jet.OLEDB.4.0; Data Source=" & Server.MapPath("commenti.mdb")
set conn = Server.CreateObject("ADODB.Connection")
conn.Open strConn
'Inserimento nuovo commento
If Len(Request.Form("nome"))>3 and Len(Request.Form("commento"))>5 then
conn.Execute "INSERT INTO commenti (nome, commento, pagina, IP) VALUES (" & _
"'" & Replace(Request.Form("nome"), "'", "''") & "', " & _
"'" & Replace(Request.Form("commento"), "'", "''") & "', " & _
"'" & Replace(Request.Form("pagina"), "'", "''") & "', " & _
"'" & Request.ServerVariables("REMOTE_ADDR") & "')"
Response.Write ("<p>Commento aggiunto!</p>")
end if
Response.Write("<h3>Commenti presenti</h3>")
' estrai record
set rs = Conn.Execute("SELECT nome, commento FROM commenti WHERE Pagina = '" & Replace(pagina, "'", "''") & "'")
' non ci sono record
if rs.Eof then Response.Write("<p>Non ci sono ancora commenti!</p>")
' ciclo su tutti i record
do until rs.eof
Response.Write("<p><b>" & Server.HtmlEncode(rs("nome")) & "</b>: ")
Response.Write(Server.HtmlEncode(rs("commento")) & "</p>")
rs.moveNext
loop
%>
<h3>Inserisci il tuo commento</h3>
<form method="post">
<input type="hidden" name="pagina" value="<%=pagina%>">
Nome: <input type="text" name="nome"><br>
Commento: <textarea name="commento" cols="30" rows="5"></textarea><br>
<input type="submit" value="Lascia commento">
</form>
<%
conn.Close
set conn = Nothing
End Sub
%>Il database ed un file di esempio sono nell'allegato.
Commenti
Per inserire un commento, devi avere un account.
Fai il login e torna a questa pagina, oppure registrati alla nostra community.
Approfondimenti
Nessuna risorsa collegata
